scale_land_dyn_bucket Module Reference

module land / dynamics / bucket More...

Functions/Subroutines
subroutine, public	land_dyn_bucket_setup
	Setup. More...
subroutine, public	land_dyn_bucket (LKMAX, LKS, LKE, LIA, LIS, LIE, LJA, LJS, LJE, TEMP_t, WATER_t, WaterLimit, ThermalCond, HeatCapacity, WaterDiff, SFLX_GH, SFLX_water, SFLX_ice, fact_land, CDZ, dt, NOWDAYSEC, TEMP, WATER, RUNOFF)
	Physical processes for land submodel. More...

Detailed Description

module land / dynamics / bucket

Description

slab-type land model

Author

Team SCALE

NAMELIST

• PARAM_LAND_DYN_BUCKET

  name	type	default value	comment
  LAND_DYN_BUCKET_NUDGING	logical	.false.	Is nudging for land physics used?
  LAND_DYN_BUCKET_NUDGING_TAU	real(DP)	0.0_DP	time constant for nudging [sec]
  LAND_DYN_BUCKET_NUDGING_TAU_UNIT	character(len=H_SHORT)	"SEC"
  LAND_DYN_BUCKET_NUDGING_BASENAME	character(len=H_LONG), dimension(FILE_EXTERNAL_INPUT_FILE_LIMIT)	''
  LAND_DYN_BUCKET_NUDGING_ENABLE_PERIODIC_YEAR	logical	.false.
  LAND_DYN_BUCKET_NUDGING_ENABLE_PERIODIC_MONTH	logical	.false.
  LAND_DYN_BUCKET_NUDGING_ENABLE_PERIODIC_DAY	logical	.false.
  LAND_DYN_BUCKET_NUDGING_STEP_FIXED	integer	0
  LAND_DYN_BUCKET_NUDGING_OFFSET	real(RP)	0.0_RP
  LAND_DYN_BUCKET_NUDGING_DEFVAL	real(RP)		= UNDEF
  LAND_DYN_BUCKET_NUDGING_CHECK_COORDINATES	logical	.true.
  LAND_DYN_BUCKET_NUDGING_STEP_LIMIT	integer	0
  LAND_DYN_BUCKET_UPDATE_BOTTOM_TEMP	logical	.false.	Is LAND_TEMP updated in the lowest level?
  LAND_DYN_BUCKET_UPDATE_BOTTOM_WATER	logical	.false.	Is LAND_WATER updated in the lowest level?

  
  

History Output

No history output

Function/Subroutine Documentation

land_dyn_bucket_setup()

subroutine, public scale_land_dyn_bucket::land_dyn_bucket_setup

(

)

Setup.

Definition at line 67 of file scale_land_dyn_bucket.F90.

References scale_calendar::calendar_unit2sec(), scale_const::const_cl, scale_const::const_dwatr, scale_const::const_undef, scale_file_external_input::file_external_input_regist(), scale_io::io_fid_conf, and scale_prc::prc_abort().

Referenced by mod_land_driver::land_driver_setup().

    use scale_prc, only: &
       prc_abort
    use scale_const, only: &
       dwatr => const_dwatr, &
       cl    => const_cl
    use scale_calendar, only: &
       calendar_unit2sec
    use scale_file_external_input, only: &
       file_external_input_regist
    use scale_const, only: &
       undef => const_undef
    implicit none

    namelist / param_land_dyn_bucket / &
       land_dyn_bucket_nudging,                       &
       land_dyn_bucket_nudging_tau,                   &
       land_dyn_bucket_nudging_tau_unit,              &
       land_dyn_bucket_nudging_basename,              &
       land_dyn_bucket_nudging_enable_periodic_year,  &
       land_dyn_bucket_nudging_enable_periodic_month, &
       land_dyn_bucket_nudging_enable_periodic_day,   &
       land_dyn_bucket_nudging_step_fixed,            &
       land_dyn_bucket_nudging_offset,                &
       land_dyn_bucket_nudging_defval,                &
       land_dyn_bucket_nudging_check_coordinates,     &
       land_dyn_bucket_nudging_step_limit,            &
       land_dyn_bucket_update_bottom_temp,            &
       land_dyn_bucket_update_bottom_water

    integer :: ierr
    !---------------------------------------------------------------------------

    log_newline
    log_info("LAND_DYN_BUCKET_setup",*) 'Setup'

    land_dyn_bucket_nudging_defval = undef

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_land_dyn_bucket,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("LAND_DYN_BUCKET_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("LAND_DYN_BUCKET_setup",*) 'Not appropriate names in namelist PARAM_LAND_DYN_BUCKET. Check!'
       call prc_abort
    endif
    log_nml(param_land_dyn_bucket)

    if ( land_dyn_bucket_nudging ) then
       call calendar_unit2sec( land_dyn_bucket_nudging_tausec, land_dyn_bucket_nudging_tau, land_dyn_bucket_nudging_tau_unit )

       log_info("LAND_DYN_BUCKET_setup",*) 'Use nudging for LAND physics  : ON'
       log_info("LAND_DYN_BUCKET_setup",*) 'Relaxation time Tau [sec]     : ', land_dyn_bucket_nudging_tausec

       if ( land_dyn_bucket_nudging_tausec == 0.0_rp ) then
          log_info("LAND_DYN_BUCKET_setup",*) 'Tau=0 means that LST is completely replaced by the external data.'
       endif

       if ( land_dyn_bucket_nudging_basename(1) == '' ) then
          log_error("LAND_DYN_BUCKET_setup",*) 'LAND_DYN_BUCKET_nudging_basename is necessary !!'
          call prc_abort
       end if

       call file_external_input_regist( land_dyn_bucket_nudging_basename(:),           & ! [IN]
                                        'LAND_TEMP',                                 & ! [IN]
                                        'LXY',                                       & ! [IN]
                                        land_dyn_bucket_nudging_enable_periodic_year,  & ! [IN]
                                        land_dyn_bucket_nudging_enable_periodic_month, & ! [IN]
                                        land_dyn_bucket_nudging_enable_periodic_day,   & ! [IN]
                                        land_dyn_bucket_nudging_step_fixed,            & ! [IN]
                                        land_dyn_bucket_nudging_offset,                & ! [IN]
                                        land_dyn_bucket_nudging_defval,                & ! [IN]
                                        land_dyn_bucket_nudging_check_coordinates,     & ! [IN]
                                        land_dyn_bucket_nudging_step_limit             ) ! [IN]

       call file_external_input_regist( land_dyn_bucket_nudging_basename(:),           & ! [IN]
                                        'LAND_WATER',                                & ! [IN]
                                        'LXY',                                       & ! [IN]
                                        land_dyn_bucket_nudging_enable_periodic_year,  & ! [IN]
                                        land_dyn_bucket_nudging_enable_periodic_month, & ! [IN]
                                        land_dyn_bucket_nudging_enable_periodic_day,   & ! [IN]
                                        land_dyn_bucket_nudging_step_fixed,            & ! [IN]
                                        land_dyn_bucket_nudging_offset,                & ! [IN]
                                        land_dyn_bucket_nudging_defval,                & ! [IN]
                                        land_dyn_bucket_nudging_check_coordinates,     & ! [IN]
                                        land_dyn_bucket_nudging_step_limit             ) ! [IN]

       log_info("LAND_DYN_BUCKET_setup",*) 'Use nudging for Land physics: ON'
    else
       log_info("LAND_DYN_BUCKET_setup",*) 'Use nudging for Land physics: OFF'
    end if

    water_denscs = dwatr * cl

    log_newline
    log_info("LAND_DYN_BUCKET_setup",*) 'Update soil temperature of bottom layer? : ', land_dyn_bucket_update_bottom_temp
    log_info("LAND_DYN_BUCKET_setup",*) 'Update soil moisture    of bottom layer? : ', land_dyn_bucket_update_bottom_water

    return

Here is the call graph for this function:

Here is the caller graph for this function:

land_dyn_bucket()

subroutine, public scale_land_dyn_bucket::land_dyn_bucket	(	integer, intent(in)	LKMAX,
		integer, intent(in)	LKS,
		integer, intent(in)	LKE,
		integer, intent(in)	LIA,
		integer, intent(in)	LIS,
		integer, intent(in)	LIE,
		integer, intent(in)	LJA,
		integer, intent(in)	LJS,
		integer, intent(in)	LJE,
		real(rp), dimension (lkmax,lia,lja), intent(in)	TEMP_t,
		real(rp), dimension (lkmax,lia,lja), intent(in)	WATER_t,
		real(rp), dimension (lia,lja), intent(in)	WaterLimit,
		real(rp), dimension (lia,lja), intent(in)	ThermalCond,
		real(rp), dimension(lia,lja), intent(in)	HeatCapacity,
		real(rp), dimension (lia,lja), intent(in)	WaterDiff,
		real(rp), dimension (lia,lja), intent(in)	SFLX_GH,
		real(rp), dimension (lia,lja), intent(in)	SFLX_water,
		real(rp), dimension (lia,lja), intent(in)	SFLX_ice,
		real(rp), dimension (lia,lja), intent(in)	fact_land,
		real(rp), dimension (lkmax), intent(in)	CDZ,
		real(dp), intent(in)	dt,
		real(dp), intent(in)	NOWDAYSEC,
		real(rp), dimension (lkmax,lia,lja), intent(inout)	TEMP,
		real(rp), dimension(lkmax,lia,lja), intent(inout)	WATER,
		real(rp), dimension(lia,lja), intent(out)	RUNOFF
	)

Physical processes for land submodel.

Definition at line 182 of file scale_land_dyn_bucket.F90.

References scale_const::const_dwatr, scale_const::const_emelt, scale_const::const_tem00, and scale_prc::prc_abort().

Referenced by mod_land_driver::land_driver_update().

    use scale_const, only: &
       tem00 => const_tem00, &
       dwatr => const_dwatr, &
       emelt => const_emelt
    use scale_prc, only: &
       prc_abort
    use scale_file_external_input, only: &
       file_external_input_update
    use scale_matrix, only: &
       matrix_solver_tridiagonal
    implicit none
    integer, intent(in) :: lkmax, lks, lke
    integer, intent(in) :: lia, lis, lie
    integer, intent(in) :: lja, ljs, lje

    real(RP), intent(in) :: temp_t      (lkmax,lia,lja)
    real(RP), intent(in) :: water_t     (lkmax,lia,lja)
    real(RP), intent(in) :: waterlimit  (lia,lja)
    real(RP), intent(in) :: thermalcond (lia,lja)
    real(RP), intent(in) :: heatcapacity(lia,lja)
    real(RP), intent(in) :: waterdiff   (lia,lja)
    real(RP), intent(in) :: sflx_gh     (lia,lja) ! positive for downward
    real(RP), intent(in) :: sflx_water  (lia,lja) ! positive for downward
    real(RP), intent(in) :: sflx_ice    (lia,lja) ! positive for downward
    real(RP), intent(in) :: fact_land   (lia,lja)
    real(RP), intent(in) :: cdz         (lkmax)
    real(DP), intent(in) :: dt
    real(DP), intent(in) :: nowdaysec

    real(RP), intent(inout) :: temp (lkmax,lia,lja)
    real(RP), intent(inout) :: water(lkmax,lia,lja)

    real(RP), intent(out) :: runoff(lia,lja)

    logical :: solve_matrix
    logical :: error

    real(RP) :: temp1 (lkmax,lia,lja)
    real(RP) :: water1(lkmax,lia,lja)

    real(RP) :: land_denscs(lkmax,lia,lja)
    real(RP) :: thermaldiff(lkmax,lia,lja)

    real(RP) :: u(lkmax,lia,lja)
    real(RP) :: m(lkmax,lia,lja)
    real(RP) :: l(lkmax,lia,lja)
    real(RP) :: v(lkmax,lia,lja)

    real(RP) :: ndg_temp (lkmax,lia,lja)
    real(RP) :: ndg_water(lkmax,lia,lja)

    real(RP) :: q

    integer :: k, i, j
    !---------------------------------------------------------------------------

    log_progress(*) 'land / dynamics / bucket'

    if( land_dyn_bucket_nudging ) then

      call file_external_input_update( &
                          'LAND_TEMP', & ! (in)
                          nowdaysec,   & ! (in)
                          temp1,       & ! (out)
                          error        ) ! (out)
      if ( error ) then
         log_error("LAND_DYN_BUCKET",*) 'Requested data is not found!'
         call prc_abort
      end if

      call file_external_input_update( &
                         'LAND_WATER', & ! (in)
                         nowdaysec,    & ! (in)
                         water1,       & ! (out)
                         error         ) ! (out)
      if ( error ) then
         log_error("LAND_DYN_BUCKET",*) 'Requested data is not found!'
         call prc_abort
      end if

      if( land_dyn_bucket_nudging_tau > 0.0_rp ) then
        ! nudging is used
        solve_matrix = .true.

        !$omp parallel do
        do j = ljs,lje
        do i = lis,lie
        do k = lks,lke
           ndg_temp(k,i,j) = ( temp1(k,i,j) - temp(k,i,j) ) / land_dyn_bucket_nudging_tausec * dt
           ndg_water(k,i,j) = ( water1(k,i,j) - water(k,i,j) ) / land_dyn_bucket_nudging_tausec * dt
        end do
        end do
        end do

      else
        ! replace data to reference
        solve_matrix = .false.

      end if

    else
      ! nudging is NOT used
      solve_matrix = .true.

      ndg_temp(:,:,:) = 0.0_rp
      ndg_water(:,:,:) = 0.0_rp

    end if

    if( solve_matrix ) then

      ! Solve diffusion of soil moisture (tridiagonal matrix)
      do j = ljs, lje
      do i = lis, lie
        l(lks,i,j) = 0.0_rp
        u(lks,i,j) = -2.0_rp * waterdiff(i,j) / ( cdz(lks) * ( cdz(lks) + cdz(lks+1) ) ) * dt
        l(lke,i,j) = -2.0_rp * waterdiff(i,j) / ( cdz(lke) * ( cdz(lke) + cdz(lke-1) ) ) * dt
        u(lke,i,j) = 0.0_rp

        m(lks,i,j) = 1.0_rp - l(lks,i,j) - u(lks,i,j)
        m(lke,i,j) = 1.0_rp - l(lke,i,j) - u(lke,i,j)
      end do
      end do

      do j = ljs, lje
      do i = lis, lie
      do k = lks+1, lke-1
        l(k,i,j) = -2.0_rp * waterdiff(i,j) / ( cdz(k) * ( cdz(k) + cdz(k-1) ) ) * dt
        u(k,i,j) = -2.0_rp * waterdiff(i,j) / ( cdz(k) * ( cdz(k) + cdz(k+1) ) ) * dt
        m(k,i,j) = 1.0_rp - l(k,i,j) - u(k,i,j)
      end do
      end do
      end do

      ! input from atmosphere
      do j = ljs, lje
      do i = lis, lie
        v(lks,i,j) = water(lks,i,j) + ndg_water(lks,i,j) &
                   + ( sflx_water(i,j) + sflx_ice(i,j) ) / ( cdz(lks) * dwatr ) * dt
      end do
      end do

      do j = ljs, lje
      do i = lis, lie
      do k = lks+1, lke
        v(k,i,j) = water(k,i,j) + ndg_water(k,i,j)
      end do
      end do
      end do

      call matrix_solver_tridiagonal( lkmax,         & ! [IN]
                                      lia, lis, lie, & ! [IN]
                                      lja, ljs, lje, & ! [IN]
                                      u(:,:,:), & ! [IN]
                                      m(:,:,:), & ! [IN]
                                      l(:,:,:), & ! [IN]
                                      v(:,:,:), & ! [IN]
                                      water1(:,:,:)  ) ! [OUT]

      if ( .not. land_dyn_bucket_update_bottom_water ) then
        do j = ljs, lje
        do i = lis, lie
          water1(lke,i,j) = water(lke,i,j)
        end do
        end do
      endif

      ! runoff of soil moisture (vertical sum)
      do j = ljs, lje
      do i = lis, lie
        runoff(i,j) = 0.0_rp
        do k = lks, lke
          runoff(i,j) = runoff(i,j) + max( water1(k,i,j) - waterlimit(i,j), 0.0_rp ) * cdz(k) * dwatr
          water1(k,i,j) = min( water1(k,i,j), waterlimit(i,j) )
        end do
      end do
      end do

      ! estimate thermal diffusivity
      do j = ljs, lje
      do i = lis, lie
      do k = lks, lke
        land_denscs(k,i,j) = ( 1.0_rp - waterlimit(i,j) ) * heatcapacity(i,j) + water_denscs * water1(k,i,j)
        thermaldiff(k,i,j) = thermalcond(i,j) / land_denscs(k,i,j)
      end do
      end do
      end do

      ! Solve diffusion of soil temperature (tridiagonal matrix)
      do j = ljs, lje
      do i = lis, lie
        l(lks,i,j) = 0.0_rp
        u(lks,i,j) = -2.0_rp * thermaldiff(lks,i,j) / ( cdz(lks) * ( cdz(lks) + cdz(lks+1) ) ) * dt
        l(lke,i,j) = -2.0_rp * thermaldiff(lke,i,j) / ( cdz(lke) * ( cdz(lke) + cdz(lke-1) ) ) * dt
        u(lke,i,j) = 0.0_rp

        m(lks,i,j) = 1.0_rp - l(lks,i,j) - u(lks,i,j)
        m(lke,i,j) = 1.0_rp - l(lke,i,j) - u(lke,i,j)
      end do
      end do

      do j = ljs, lje
      do i = lis, lie
      do k = lks+1, lke-1
        l(k,i,j) = -2.0_rp * thermaldiff(k,i,j) / ( cdz(k) * ( cdz(k) + cdz(k-1) ) ) * dt
        u(k,i,j) = -2.0_rp * thermaldiff(k,i,j) / ( cdz(k) * ( cdz(k) + cdz(k+1) ) ) * dt
        m(k,i,j) = 1.0_rp - l(k,i,j) - u(k,i,j)
      end do
      end do
      end do

      ! input from atmosphere
      do j = ljs, lje
      do i = lis, lie
         ! tentative (MUST consider ice water explicitly)
         q = sflx_gh(i,j)
         if ( temp(lks,i,j) >= tem00 ) q = q - sflx_ice(i,j) * emelt
         v(lks,i,j) = temp(lks,i,j) + ndg_temp(lks,i,j) + temp_t(lks,i,j) &
                    + q / ( land_denscs(lks,i,j) * cdz(lks) ) * dt
      end do
      end do

      do j = ljs, lje
      do i = lis, lie
      do k = lks+1, lke
        v(k,i,j) = temp(k,i,j) + ndg_temp(k,i,j) + temp_t(k,i,j)
      end do
      end do
      end do

      call matrix_solver_tridiagonal( lkmax,         & ! [IN]
                                      lia, lis, lie, & ! [IN]
                                      lja, ljs, lje, & ! [IN]
                                      u(:,:,:),  & ! [IN]
                                      m(:,:,:),  & ! [IN]
                                      l(:,:,:),  & ! [IN]
                                      v(:,:,:),  & ! [IN]
                                      temp1(:,:,:)   ) ! [OUT]

      if ( .not. land_dyn_bucket_update_bottom_temp ) then
        do j = ljs, lje
        do i = lis, lie
          temp1(lke,i,j) = temp(lke,i,j)
        end do
        end do
      endif

    end if

    ! calculate tendency
    do j = ljs, lje
    do i = lis, lie
      if( fact_land(i,j) > 0.0_rp ) then
         do k = lks, lke
            temp(k,i,j) = temp1(k,i,j)
            water(k,i,j) = water1(k,i,j)
         end do
      end if
    end do
    end do

    return

Here is the call graph for this function:

Here is the caller graph for this function: