scale_ocean_phy_roughness_miller92.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module scale_ocean_phy_roughness_miller92
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: ocean_phy_roughness_miller92_setup
  public :: ocean_phy_roughness_miller92

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  real(RP), private :: ocean_phy_roughness_miller92_cm0   = 1.0e-3_rp ! bulk coef. for U*
  real(RP), private :: ocean_phy_roughness_miller92_z0mi  = 0.0e-0_rp ! base roughness length for momentum
  real(RP), private :: ocean_phy_roughness_miller92_z0mr  = 1.8e-2_rp ! rough factor          for momentum
  real(RP), private :: ocean_phy_roughness_miller92_z0ms  = 1.1e-1_rp ! smooth factor         for momentum
  real(RP), private :: ocean_phy_roughness_miller92_z0hi  = 1.4e-5_rp ! base roughness length for heat
  real(RP), private :: ocean_phy_roughness_miller92_z0hr  = 0.0e-0_rp ! rough factor          for heat
  real(RP), private :: ocean_phy_roughness_miller92_z0hs  = 4.0e-1_rp ! smooth factor         for heat
  real(RP), private :: ocean_phy_roughness_miller92_z0ei  = 1.3e-4_rp ! base roughness length for moisture
  real(RP), private :: ocean_phy_roughness_miller92_z0er  = 0.0e-0_rp ! rough factor          for moisture
  real(RP), private :: ocean_phy_roughness_miller92_z0es  = 6.2e-1_rp ! smooth factor         for moisture

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine ocean_phy_roughness_miller92_setup
    use scale_prc, only: &
       prc_abort
    use scale_ocean_phy_roughness, only: &
       ocean_phy_roughness_setup
    implicit none

    namelist / param_ocean_phy_roughness_miller92 / &
       ocean_phy_roughness_miller92_cm0,  &
       ocean_phy_roughness_miller92_z0mi, &
       ocean_phy_roughness_miller92_z0mr, &
       ocean_phy_roughness_miller92_z0ms, &
       ocean_phy_roughness_miller92_z0hi, &
       ocean_phy_roughness_miller92_z0hr, &
       ocean_phy_roughness_miller92_z0hs, &
       ocean_phy_roughness_miller92_z0ei, &
       ocean_phy_roughness_miller92_z0er, &
       ocean_phy_roughness_miller92_z0es

    integer :: ierr
    !---------------------------------------------------------------------------

    ! common setup
    call ocean_phy_roughness_setup

    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_ocean_phy_roughness_miller92,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("OCEAN_PHY_ROUGHNESS_miller92_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("OCEAN_PHY_ROUGHNESS_miller92_setup",*) 'Not appropriate names in namelist PARAM_OCEAN_PHY_ROUGHNESS_MILLER92. Check!'
       call prc_abort
    endif
    log_nml(param_ocean_phy_roughness_miller92)

    return
  end subroutine ocean_phy_roughness_miller92_setup

  !-----------------------------------------------------------------------------
  subroutine ocean_phy_roughness_miller92( &
       OIA, OIS, OIE, &
       OJA, OJS, OJE, &
       Uabs,          &
       Z0M, Z0H, Z0E  )
    use scale_const, only: &
       grav => const_grav
    use scale_ocean_phy_roughness, only: &
       ocean_phy_roughness_visck, &
       ocean_phy_roughness_ustar_min, &
       ocean_phy_roughness_z0m_min, &
       ocean_phy_roughness_z0h_min, &
       ocean_phy_roughness_z0e_min
    implicit none

    integer,  intent(in)  :: OIA, OIS, OIE
    integer,  intent(in)  :: OJA, OJS, OJE
    real(RP), intent(in)  :: Uabs(oia,oja) ! velocity at the lowest atomspheric layer [m/s]
    real(RP), intent(out) :: Z0M (oia,oja) ! roughness length for momentum [m]
    real(RP), intent(out) :: Z0H (oia,oja) ! roughness length for heat [m]
    real(RP), intent(out) :: Z0E (oia,oja) ! roughness length for vapor [m]

    real(RP) :: Ustar

    integer  :: i, j
    !---------------------------------------------------------------------------

    !$omp parallel do private(Ustar)
    do j = ojs, oje
    do i = ois, oie
       ustar = max( sqrt( ocean_phy_roughness_miller92_cm0 ) * uabs(i,j), ocean_phy_roughness_ustar_min )

       z0m(i,j) = max( ocean_phy_roughness_miller92_z0mi &
                     + ocean_phy_roughness_miller92_z0mr / grav * ustar * ustar &
                     + ocean_phy_roughness_miller92_z0ms * ocean_phy_roughness_visck / ustar, &
                       ocean_phy_roughness_z0m_min )
       z0h(i,j) = max( ocean_phy_roughness_miller92_z0hi &
                     + ocean_phy_roughness_miller92_z0hr / grav * ustar * ustar &
                     + ocean_phy_roughness_miller92_z0hs * ocean_phy_roughness_visck / ustar, &
                       ocean_phy_roughness_z0h_min )
       z0e(i,j) = max( ocean_phy_roughness_miller92_z0ei &
                     + ocean_phy_roughness_miller92_z0er / grav * ustar * ustar &
                     + ocean_phy_roughness_miller92_z0es * ocean_phy_roughness_visck / ustar, &
                       ocean_phy_roughness_z0e_min )
    enddo
    enddo

    return
  end subroutine ocean_phy_roughness_miller92

end module scale_ocean_phy_roughness_miller92