mod_atmos_phy_cp_driver.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "inc_openmp.h"
module mod_atmos_phy_cp_driver
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_stdio
  use scale_prof
  use scale_grid_index
  use scale_tracer
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: atmos_phy_cp_driver_setup
  public :: atmos_phy_cp_driver_resume
  public :: atmos_phy_cp_driver

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_driver_setup
    use scale_atmos_phy_cp, only: &
         atmos_phy_cp_setup
    use mod_atmos_admin, only: &
       atmos_phy_cp_type, &
       atmos_sw_phy_cp
    implicit none
    !---------------------------------------------------------------------------

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ Module[DRIVER] / Categ[ATMOS PHY_CP] / Origin[SCALE-RM]'

    if ( atmos_sw_phy_cp ) then

       ! setup library component
       call atmos_phy_cp_setup( atmos_phy_cp_type )

    else
       if( io_l ) write(io_fid_log,*) '*** this component is never called.'
    endif

    return
  end subroutine atmos_phy_cp_driver_setup

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_driver_resume
    use mod_atmos_admin, only: &
       atmos_sw_phy_cp
    implicit none

    if ( atmos_sw_phy_cp ) then

       ! run once (only for the diagnostic value)
       call prof_rapstart('ATM_Cumulus', 1)
       call atmos_phy_cp_driver( update_flag = .true. )
       call prof_rapend  ('ATM_Cumulus', 1)

    endif

    return
  end subroutine atmos_phy_cp_driver_resume

  !-----------------------------------------------------------------------------
  subroutine atmos_phy_cp_driver( update_flag )
    use scale_time, only: &
       dt_cp => time_dtsec_atmos_phy_cp
    use scale_rm_statistics, only: &
       statistics_checktotal, &
       stat_total
    use scale_history, only: &
       hist_in
    use scale_atmos_phy_cp, only: &
       atmos_phy_cp
    use mod_atmos_vars, only: &
       dens,              &
       momz,              &
       momx,              &
       momy,              &
       rhot,              &
       qtrc,              &
       dens_t => dens_tp, &
       momz_t => momz_tp, &
       momx_t => momx_tp, &
       momy_t => momy_tp, &
       rhot_t => rhot_tp, &
       rhoq_t => rhoq_tp
    use mod_atmos_phy_cp_vars, only: &
       dens_t_cp      => atmos_phy_cp_dens_t,         &
       momz_t_cp      => atmos_phy_cp_momz_t,         &
       momx_t_cp      => atmos_phy_cp_momx_t,         &
       momy_t_cp      => atmos_phy_cp_momy_t,         &
       rhot_t_cp      => atmos_phy_cp_rhot_t,         &
       rhoq_t_cp      => atmos_phy_cp_rhoq_t,         &
       mflx_cloudbase => atmos_phy_cp_mflx_cloudbase, &
       sflx_rain      => atmos_phy_cp_sflx_rain,      &  ! convective rain [kg/m2/s]
       cloudtop       => atmos_phy_cp_cloudtop,       &  ! cloud top height [m]
       cloudbase      => atmos_phy_cp_cloudbase,      &  ! cloud base height [m]
       cldfrac_dp     => atmos_phy_cp_cldfrac_dp,     &  ! cloud fraction (deep convection) [0-1]
       cldfrac_sh     => atmos_phy_cp_cldfrac_sh,     &  ! cloud fraction (shallow convection) [0-1]
       kf_nca         => atmos_phy_cp_kf_nca,         &  ! advection/cumulus convection timescale/dt for KF [step]
       kf_w0avg       => atmos_phy_cp_kf_w0avg           ! rannning mean vertical wind velocity      for KF [m/s]
    implicit none

    logical, intent(in) :: update_flag

    real(RP) :: total ! dummy

    integer  :: k, i, j, iq
    !---------------------------------------------------------------------------

    if ( update_flag ) then

       call atmos_phy_cp( dens,           & ! [IN]
                          momz,           & ! [IN]
                          momx,           & ! [IN]
                          momy,           & ! [IN]
                          rhot,           & ! [IN]
                          qtrc,           & ! [IN]
                          dens_t_cp,      & ! [INOUT]
                          momz_t_cp,      & ! [INOUT]
                          momx_t_cp,      & ! [INOUT]
                          momy_t_cp,      & ! [INOUT]
                          rhot_t_cp,      & ! [INOUT]
                          rhoq_t_cp,      & ! [INOUT]
                          mflx_cloudbase, & ! [INOUT]
                          sflx_rain,      & ! [OUT]
                          cloudtop,       & ! [OUT]
                          cloudbase,      & ! [OUT]
                          cldfrac_dp,     & ! [OUT]
                          cldfrac_sh,     & ! [OUT]
                          kf_nca,         & ! [OUT]
                          kf_w0avg        ) ! [OUT]

       ! tentative reset
!OCL XFILL
       do j  = js, je
       do i  = is, ie
       do k  = ks, ke
          momz_t_cp(k,i,j) = 0.0_rp
          momx_t_cp(k,i,j) = 0.0_rp
          momy_t_cp(k,i,j) = 0.0_rp
       enddo
       enddo
       enddo

!OCL XFILL
       do j  = js, je
       do i  = is, ie
          mflx_cloudbase(i,j) = 0.0_rp
       enddo
       enddo

       call hist_in( mflx_cloudbase(:,:),   'CBMFX',     'cloud base mass flux',             'kg/m2/s', nohalo=.true. )
       call hist_in( sflx_rain(:,:),   'RAIN_CP',   'surface rain rate by CP',          'kg/m2/s', nohalo=.true. )
       call hist_in( sflx_rain(:,:),   'PREC_CP',   'surface precipitation rate by CP', 'kg/m2/s', nohalo=.true. )
       call hist_in( cloudtop(:,:),   'CUMHGT',    'CP cloud top height',              'm',       nohalo=.true. )
       call hist_in( cloudbase(:,:),   'CUBASE',    'CP cloud base height',             'm',       nohalo=.true. )
       call hist_in( cldfrac_dp(:,:,:), 'CUMFRC_DP', 'CP cloud fraction (deep)',         '0-1',     nohalo=.true. )
       call hist_in( cldfrac_sh(:,:,:), 'CUMFRC_SH', 'CP cloud fraction (shallow)',      '0-1',     nohalo=.true. )

       call hist_in( kf_nca(:,:),   'kf_nca',    'advection or cumulus convection timescale for KF', 's',       nohalo=.true. )
       call hist_in( kf_w0avg(:,:,:), 'kf_w0avg',  'rannning mean vertical wind velocity for KF',      'kg/m2/s', nohalo=.true. )

       call hist_in( dens_t_cp(:,:,:), 'DENS_t_CP', 'tendency DENS in CP', 'kg/m3/s'  , nohalo=.true. )
       call hist_in( momz_t_cp(:,:,:), 'MOMZ_t_CP', 'tendency MOMZ in CP', 'kg/m2/s2' , nohalo=.true. )
       call hist_in( momx_t_cp(:,:,:), 'MOMX_t_CP', 'tendency MOMX in CP', 'kg/m2/s2' , nohalo=.true. )
       call hist_in( momy_t_cp(:,:,:), 'MOMY_t_CP', 'tendency MOMY in CP', 'kg/m2/s2' , nohalo=.true. )
       call hist_in( rhot_t_cp(:,:,:), 'RHOT_t_CP', 'tendency RHOT in CP', 'K*kg/m3/s', nohalo=.true. )

       do iq = 1, qa
          call hist_in( rhoq_t_cp(:,:,:,iq), trim(aq_name(iq))//'_t_CP', &
                        'tendency rho*'//trim(aq_name(iq))//'in CP', 'kg/m3/s', nohalo=.true. )
       enddo

    endif

    !$omp parallel do private(i,j,k) OMP_SCHEDULE_ collapse(2)
    do j = js, je
    do i = is, ie
    do k = ks, ke
       dens_t(k,i,j) = dens_t(k,i,j) + dens_t_cp(k,i,j)
       momz_t(k,i,j) = momz_t(k,i,j) + momz_t_cp(k,i,j)
       momx_t(k,i,j) = momx_t(k,i,j) + momx_t_cp(k,i,j)
       momy_t(k,i,j) = momy_t(k,i,j) + momy_t_cp(k,i,j)
       rhot_t(k,i,j) = rhot_t(k,i,j) + rhot_t_cp(k,i,j)
    enddo
    enddo
    enddo

    !$omp parallel do private(i,j,k) OMP_SCHEDULE_ collapse(3)
    do iq = 1,  qa
    do j  = js, je
    do i  = is, ie
    do k  = ks, ke
       rhoq_t(k,i,j,iq) = rhoq_t(k,i,j,iq) + rhoq_t_cp(k,i,j,iq)
    enddo
    enddo
    enddo
    enddo

    if ( statistics_checktotal ) then
       call stat_total( total, dens_t_cp(:,:,:), 'DENS_t_CP' )
       call stat_total( total, momz_t_cp(:,:,:), 'MOMZ_t_CP' )
       call stat_total( total, momx_t_cp(:,:,:), 'MOMX_t_CP' )
       call stat_total( total, momy_t_cp(:,:,:), 'MOMY_t_CP' )
       call stat_total( total, rhot_t_cp(:,:,:), 'RHOT_t_CP' )

       do iq = 1, qa
          call stat_total( total, rhoq_t_cp(:,:,:,iq), trim(aq_name(iq))//'_t_CP' )
       enddo
    endif

    return
  end subroutine atmos_phy_cp_driver

end module mod_atmos_phy_cp_driver