mod_rm_driver.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
module mod_rm_driver
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use dc_log, only: &
     loginit
  use gtool_file, only: &
     filecloseall
  use scale_precision
  use scale_stdio
  use scale_prof
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ included parameters
  !
#include "scale-rm.h"
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: scalerm

  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  character(len=H_MID), private, parameter :: modelname = "SCALE-RM ver. "//version

  !-----------------------------------------------------------------------------
contains
  !-----------------------------------------------------------------------------
  subroutine scalerm( &
       comm_world,       &
       intercomm_parent, &
       intercomm_child,  &
       cnf_fname         )
    use scale_process, only: &
       prc_local_setup
    use scale_rm_process, only: &
       prc_setup
    use scale_const, only: &
       const_setup
    use scale_calendar, only: &
       calendar_setup
    use scale_random, only: &
       random_setup
    use scale_grid_index, only: &
       grid_index_setup
    use scale_grid, only: &
       grid_setup
    use scale_grid_nest, only: &
       nest_setup
    use scale_land_grid_index, only: &
       land_grid_index_setup
    use scale_land_grid, only: &
       land_grid_setup
    use scale_urban_grid_index, only: &
       urban_grid_index_setup
    use scale_urban_grid, only: &
       urban_grid_setup
    use scale_tracer, only: &
       tracer_setup
    use scale_fileio, only: &
       fileio_setup
    use scale_comm, only: &
       comm_setup , &
       comm_cleanup
    use scale_topography, only: &
       topo_setup
    use scale_landuse, only: &
       landuse_setup
    use scale_grid_real, only: &
       real_setup
    use scale_gridtrans, only: &
       gtrans_setup
    use scale_interpolation, only: &
       interp_setup
    use scale_rm_statistics, only: &
       stat_setup
    use scale_history, only: &
       hist_setup, &
       hist_write
    use scale_monitor, only: &
       monit_setup, &
       monit_write, &
       monit_finalize
    use scale_external_input, only: &
       extin_setup
    use scale_atmos_hydrostatic, only: &
       atmos_hydrostatic_setup
    use scale_atmos_thermodyn, only: &
       atmos_thermodyn_setup
    use scale_atmos_saturation, only: &
       atmos_saturation_setup
    use scale_bulkflux, only: &
       bulkflux_setup
    use scale_roughness, only: &
       roughness_setup

    use mod_admin_restart, only: &
       admin_restart_setup, &
       admin_restart
    use mod_admin_time, only: &
       admin_time_setup,      &
       admin_time_checkstate, &
       admin_time_advance,    &
       time_doatmos_step,     &
       time_doland_step,      &
       time_dourban_step,     &
       time_doocean_step,     &
       time_doatmos_restart,  &
       time_doland_restart,   &
       time_dourban_restart,  &
       time_doocean_restart,  &
       time_doresume,         &
       time_doend
    use mod_atmos_admin, only: &
       atmos_admin_setup, &
       atmos_do
    use mod_atmos_vars, only: &
       atmos_vars_setup,                         &
       atmos_sw_restart => atmos_restart_output, &
       atmos_vars_restart_write,                 &
       atmos_sw_check => atmos_restart_check,    &
       atmos_vars_restart_check
    use mod_atmos_driver, only: &
       atmos_driver_setup,    &
       atmos_driver,           &
       atmos_driver_finalize
    use mod_ocean_admin, only: &
       ocean_admin_setup, &
       ocean_do
    use mod_ocean_vars, only: &
       ocean_vars_setup,                         &
       ocean_sw_restart => ocean_restart_output, &
       ocean_vars_restart_write
    use mod_ocean_driver, only: &
       ocean_driver_setup, &
       ocean_driver
    use mod_land_admin, only: &
       land_admin_setup, &
       land_do
    use mod_land_vars, only: &
       land_vars_setup,                        &
       land_sw_restart => land_restart_output, &
       land_vars_restart_write
    use mod_land_driver, only: &
       land_driver_setup, &
       land_driver
    use mod_urban_admin, only: &
       urban_admin_setup, &
       urban_do
    use mod_urban_vars, only: &
       urban_vars_setup,                         &
       urban_sw_restart => urban_restart_output, &
       urban_vars_restart_write
    use mod_urban_driver, only: &
       urban_driver_setup, &
       urban_driver
    use mod_cpl_admin, only: &
       cpl_admin_setup
    use mod_cpl_vars, only: &
       cpl_vars_setup
    use mod_user, only: &
       user_setup, &
       user_step
    implicit none

    integer,               intent(in) :: comm_world
    integer,               intent(in) :: intercomm_parent
    integer,               intent(in) :: intercomm_child
    character(len=H_LONG), intent(in) :: cnf_fname

    integer :: myrank
    logical :: ismaster
    !---------------------------------------------------------------------------

    !########## Initial setup ##########

    ! setup standard I/O
    call io_setup( modelname, .true., cnf_fname )

    ! setup MPI
    call prc_local_setup( comm_world, & ! [IN]
                          myrank,     & ! [OUT]
                          ismaster    ) ! [OUT]

    ! setup Log
    call io_log_setup( myrank, ismaster )
    call loginit( io_fid_conf, io_fid_log, io_l )

    ! setup process
    call prc_setup

    ! setup PROF
    call prof_setup


    ! profiler start
    call prof_setprefx('INIT')
    call prof_rapstart('Initialize', 0)


    ! setup constants
    call const_setup

    ! setup calendar
    call calendar_setup

    ! setup random number
    call random_setup

    ! setup horizontal/vertical grid coordinates (cartesian,idealized)
    call grid_index_setup
    call grid_setup

    call land_grid_index_setup
    call land_grid_setup

    call urban_grid_index_setup
    call urban_grid_setup

    ! setup tracer index
    call tracer_setup

    ! setup file I/O
    call fileio_setup

    ! setup mpi communication
    call comm_setup

    ! setup topography
    call topo_setup
    ! setup land use category index/fraction
    call landuse_setup
    ! setup grid coordinates (real world)
    call real_setup

    ! setup grid transfer metrics (uses in ATMOS_dynamics)
    call gtrans_setup
    ! setup Z-ZS interpolation factor (uses in History)
    call interp_setup

    ! setup restart
    call admin_restart_setup
    ! setup time
    call admin_time_setup( setup_timeintegration = .true. )
    ! setup statistics
    call stat_setup
    ! setup history I/O
    call hist_setup
    ! setup monitor I/O
    call monit_setup
    ! setup external in
    call extin_setup

    ! setup nesting grid
    call nest_setup ( intercomm_parent, intercomm_child )

    ! setup common tools
    call atmos_hydrostatic_setup
    call atmos_thermodyn_setup
    call atmos_saturation_setup

    call bulkflux_setup
    call roughness_setup

    ! setup submodel administrator
    call atmos_admin_setup
    call ocean_admin_setup
    call land_admin_setup
    call urban_admin_setup
    call cpl_admin_setup

    ! setup variable container
    call atmos_vars_setup
    call ocean_vars_setup
    call land_vars_setup
    call urban_vars_setup
    call cpl_vars_setup

    ! setup submodel driver
    call atmos_driver_setup
    call ocean_driver_setup
    call land_driver_setup
    call urban_driver_setup

    call user_setup

    call prof_rapend('Initialize', 0)

    !########## main ##########

#ifdef _FIPP_
    call fipp_start
#endif
#ifdef _PAPI_
    call prof_papi_rapstart
#endif

    if( io_l ) write(io_fid_log,*)
    if( io_l ) write(io_fid_log,*) '++++++ START TIMESTEP ++++++'
    call prof_setprefx('MAIN')
    call prof_rapstart('Main_Loop', 0)

    do

      ! report current time
      call admin_time_checkstate

      if ( time_doresume ) then
         ! resume state from restart files
         call resume_state

         ! history&monitor file output
         call hist_write ! if needed
         call monit_write('MAIN')
      end if


      ! time advance
      call admin_time_advance

      ! user-defined procedure
      call user_step

      ! change to next state
      if( ocean_do .AND. time_doocean_step ) call ocean_driver
      if( land_do  .AND. time_doland_step  ) call land_driver
      if( urban_do .AND. time_dourban_step ) call urban_driver
      if( atmos_do .AND. time_doatmos_step ) call atmos_driver

      ! history&monitor file output
      call hist_write
      call monit_write('MAIN')

      ! restart output
      ! if( OCEAN_sw_restart .AND. TIME_DOOCEAN_restart ) call OCEAN_vars_restart_write
      ! if( LAND_sw_restart  .AND. TIME_DOLAND_restart  ) call LAND_vars_restart_write
      ! if( URBAN_sw_restart .AND. TIME_DOURBAN_restart ) call URBAN_vars_restart_write
      ! if( ATMOS_sw_restart .AND. TIME_DOATMOS_restart ) call ATMOS_vars_restart_write
      call admin_restart

      if( time_doend ) exit

      if( io_l ) call flush(io_fid_log)

    enddo

    call prof_rapend('Main_Loop', 0)

    if( io_l ) write(io_fid_log,*) '++++++ END TIMESTEP ++++++'
    if( io_l ) write(io_fid_log,*)


    call prof_setprefx('FIN')

    call prof_rapstart('All', 1)

    if( atmos_do ) call atmos_driver_finalize

#ifdef _FIPP_
    call fipp_stop
#endif
#ifdef _PAPI_
    call prof_papi_rapstop
#endif

    !########## Finalize ##########

    ! check data
    if( atmos_sw_check ) call atmos_vars_restart_check

    call prof_rapstart('Monit', 2)
    call monit_finalize
    call prof_rapend  ('Monit', 2)

    call comm_cleanup

    call prof_rapstart('File', 2)
    call filecloseall
    call prof_rapend  ('File', 2)

    call prof_rapend  ('All', 1)

    call prof_rapreport
#ifdef _PAPI_
    call prof_papi_rapreport
#endif

    return
  end subroutine scalerm


  subroutine resume_state
    use mod_atmos_driver, only: &
       atmos_driver_resume1,    &
       atmos_driver_resume2,    &
       atmos_surface_set
    use mod_ocean_driver, only: &
       ocean_driver_resume, &
       ocean_surface_set
    use mod_land_driver, only: &
       land_driver_resume, &
       land_surface_set
    use mod_urban_driver, only: &
       urban_driver_resume, &
       urban_surface_set
    use mod_atmos_vars, only: &
       atmos_vars_diagnostics, &
       atmos_vars_restart_read
    use mod_ocean_vars, only: &
       ocean_vars_restart_read
    use mod_land_vars, only: &
       land_vars_restart_read
    use mod_urban_vars, only: &
       urban_vars_restart_read
    use mod_user, only: &
       user_resume0, &
       user_resume
    use mod_atmos_admin, only: &
       atmos_do
    use mod_ocean_admin, only: &
       ocean_do
    use mod_land_admin, only: &
       land_do
    use mod_urban_admin, only: &
       urban_do
    implicit none

    ! read restart data
    if( atmos_do ) call atmos_vars_restart_read
    if( ocean_do ) call ocean_vars_restart_read
    if( land_do  ) call land_vars_restart_read
    if( urban_do ) call urban_vars_restart_read

    ! setup user-defined procedure before setup of other components
    call user_resume0

    ! calc diagnostics
    if( atmos_do ) call atmos_vars_diagnostics

    ! setup surface condition
    if( atmos_do ) call atmos_surface_set( countup=.false. )
    if( ocean_do ) call ocean_surface_set( countup=.false. )
    if( land_do  ) call land_surface_set ( countup=.false. )
    if( urban_do ) call urban_surface_set( countup=.false. )

    ! setup submodel driver
    if( atmos_do ) call atmos_driver_resume1
    if( ocean_do ) call ocean_driver_resume
    if( land_do  ) call land_driver_resume
    if( urban_do ) call urban_driver_resume
    if( atmos_do ) call atmos_driver_resume2

    ! setup user-defined procedure
    call user_resume

    return
  end subroutine resume_state

end module mod_rm_driver